cls
@ECHO OFF
CLS
color 0a

GOTO MENU
:MENU
ECHO. 
ECHO.               =-=-=-=-=请选择要安装的服务项目=-=-=-=-=
ECHO. 
ECHO.                       1  本机网络服务-桥接,直接连接外网
ECHO.
ECHO.                       2  USB服务
ECHO.  
ECHO.                       3  DHCP和NAT服务-共享上网,默认安装虚拟网卡8
ECHO. 
ECHO.                       4  虚拟网卡1-本地网络
ECHO.                       
ECHO.                       5  用户权限服务
ECHO.
ECHO.                       6  磁盘映射服务
ECHO.
ECHO.                       7  退   出
ECHO.
ECHO.
ECHO.
CHOICE /C 12345678 /N /M 请输入选择项目的序号：
IF ERRORLEVEL 1 IF NOT ERRORLEVEL 2 GOTO SERVICE1
IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 GOTO SERVICE2
IF ERRORLEVEL 3 IF NOT ERRORLEVEL 4 GOTO SERVICE3
IF ERRORLEVEL 4 IF NOT ERRORLEVEL 5 GOTO SERVICE4
IF ERRORLEVEL 5 IF NOT ERRORLEVEL 6 GOTO SERVICE5
IF ERRORLEVEL 6 IF NOT ERRORLEVEL 7 GOTO SERVICE6
IF ERRORLEVEL 7 GOTO END
PAUSE
:SERVICE1
echo.
echo  安装桥接服务，请稍后...
echo.
reg query HKLM\SYSTEM\CurrentControlSet\Services\vmnetuserif >nul 2>nul||(vnetlib.exe -- install userif)
ver|find "6.">nul && (copy /y BridgeWin7\*.* >nul)
ver|find "5.">nul && (copy /y BridgeWinxp\*.* >nul)
vnetlib.exe -- install bridge
vnetlib.exe -- start bridge
del vmnetbridge.dll
del vmnetbridge.sys
echo.
echo  安装桥接服务完成
echo.
GOTO MENU
:SERVICE2
echo.
echo  安装USB服务...
echo.
vnetlib.exe -- install hcmon
vnetlib.exe -- start hcmon
rundll32 setupapi,InstallHinfSection _Install1.NT 128 %cd%\vmusb.inf >nul
vnetlib.exe -- install usb
sc create VMUSBArbService binpath= "%cd%\vmware-usbarbitrator.exe"  displayname= "VMware USB Arbitration Service" start= auto
net start VMUSBArbService
echo.
echo  安装USB服务完成
echo.
GOTO MENU
:SERVICE3
echo.
echo  安装DHCP和NAT服务，时间较长，请耐心等待...
echo.
reg query HKLM\SYSTEM\CurrentControlSet\Services\vmnetuserif >nul 2>nul||(vnetlib.exe -- install userif)
reg query HKLM\SYSTEM\CurrentControlSet\Services\vmnetdhcp >nul 2>nul||(vnetlib.exe -- install dhcp)
vnetlib.exe -- install nat
vnetlib.exe -- add adapter vmnet8
vnetlib.exe -- add dhcp vmnet8
vnetlib.exe -- add nat vmnet8
vnetlib.exe -- set vnet vmnet8 addr 192.168.128.0
vnetlib.exe -- stop nat
vnetlib.exe -- stop dhcp
vnetlib.exe -- update dhcp vmnet8
vnetlib.exe -- start dhcp
vnetlib.exe -- update nat vmnet8
vnetlib.exe -- start nat
vnetlib.exe -- update adapter vmnet8
echo.
echo  安装DHCP和NAT服务完成
echo.
GOTO MENU
:SERVICE4
echo.
echo  安装虚拟网卡1，时间较长，请耐心等待...
echo.
reg query HKLM\SYSTEM\CurrentControlSet\Services\vmnetuserif >nul 2>nul||(vnetlib.exe -- install userif)
reg query HKLM\SYSTEM\CurrentControlSet\Services\vmnetdhcp >nul 2>nul||(vnetlib.exe -- install dhcp)
vnetlib.exe -- add adapter vmnet1
vnetlib.exe -- add dhcp vmnet1
vnetlib.exe -- set vnet vmnet1 addr 10.10.10.0
vnetlib.exe -- stop dhcp
vnetlib.exe -- update dhcp vmnet1
vnetlib.exe -- start dhcp
vnetlib.exe -- update adapter vmnet1
echo.
echo  安装虚拟网卡1完成
echo.
GOTO MENU
:SERVICE5
echo.
echo  安装用户权限服务...
echo.
vnetlib.exe -- install authd
vnetlib.exe -- start authd
echo.
echo  安装用户权限服务完成
echo.
GOTO MENU
:SERVICE6
echo.
echo  安装磁盘映射服务...
echo.
sc create vstor2-ws60 type= kernel start= demand binpath= "%cd%\vstor2-ws60.sys" displayname= "Vstor2 WS60 Virtual Storage Driver"
net start vstor2-ws60
echo.
echo  安装磁盘映射服务完成
echo.
GOTO MENU
:END
